10 REM EXECUTE 1 TIME TO INIT PROG
20 CLEAR : DIM S$(0)
30 PRINT "PROGRAM INITIALIZED": END 
100 "A": AREAD A: GOSUB 160: REM EURO TO ATS
110 PRINT "ATS ";A*B
120 END 
130 " ": AREAD A: GOSUB 160: REM ATS TO EURO
140 PRINT "EUR ";A/B
150 END 
160 B=13.7603: RETURN 
170 "D": AREAD A:B=0: REM BIN TO DEC
180 IF A<0 THEN 210
190 IF A <> INT A THEN 210
200 GOTO 230
210 PRINT "ILLEGAL FUNCTION ARG."
220 END 
230 IF A=0 GOTO 310
240 N= INT ( LOG A)
250 FOR I=N TO 0 STEP -1
260 B=B*2:J=10^I
270 IF A<J THEN 300
280 A=A-J:B=B+1
290 IF A>J THEN 210
300 NEXT I
310 PRINT "DEC ";B
320 END 
330 "B": AREAD A:S$(0)="":C=0: REM DEC TO BIN
340 IF A<0 THEN 370
350 IF A <> INT A THEN 370
360 GOTO 390
370 PRINT "ILLEGAL FUNCTION ARG."
380 END 
390 IF A=0 THEN 450
400 A=A/2: IF A= INT A THEN 430
410 A= INT A:S$(0)="1"+S$(0)
420 GOTO 440
430 S$(0)="0"+S$(0)
440 C=C+1: GOTO 390
450 IF C<17 THEN 480
460 PRINT "OVERFLOW"
470 END 
480 IF C=0 LET S$(0)="0"
485 IF C>8 THEN 510
490 PRINT "BIN ";S$(0)
500 END 
510 PRINT "BIN "; LEFT$ (S$(0),C-8);" "; RIGHT$ (S$(0),8)
520 END 
~