50000 "DICE"CLS :WAIT 0:DIM PT$(5)*10:DIM II(4):RANDOM 
50010 PT$(0)="0101010101"
50020 PT$(1)="397D7D7D39"
50030 PT$(2)="4161616141"
50040 PT$(3)="4040404040"
50050 PT$(4)="4E5F5F5F4E"
50060 PT$(5)="4143434341"
50070 INPUT "Number of dices? ";N:IF N<1OR N>5BEEP 1:PAUSE "Must be between 1 and 5":GOTO 50070 
50080 "LOOP1"CLS :C=0:D=0:FOR I=0TO N-1
50090 B=&55:IF II(I)>=0LET II(I)=RND 6,B=0
50100 X=1+I*4:CURSOR X,0:GPRINT C;D;0;B;127
50110 CURSOR X,1:GPRINT C;D;0;B;127:C=&7F:D=B
50120 X=X+1:ON ABS II(I)GOSUB "PNT1","PNT2","PNT3","PNT4","PNT5","PNT6"
50130 NEXT I:BEEP 1,1,20
50140 X=1+N*4:CURSOR X,0:GPRINT C;D;0;0;0
50150 CURSOR X,1:GPRINT C;D;0;0;0
50160 A=ASC INKEY$ :IF A=0THEN 50160 
50170 IF A=2CLS :END 
50180 IF A=13GOTO "LOOP1"
50190 B=A-ASC "1":IF B>=0AND B<NGOSUB "MARK":GOTO 50160 
50200 IF A=ASC "0"GOSUB "MALL":GOTO 50160 
50210 BEEP 1:GOTO 50160 
50220 "MALL"FOR B=0TO N-1
50230 IF II(B)<0GOSUB "MARK"
50240 NEXT B:RETURN 
50250 "MARK"II(B)=-II(B)
50260 X=1+B*4:C=0:D=0:E=0:IF II(B)<0LET C=&55
50270 IF B<=0GOTO 50300 
50280 IF II(B-1)<0LET D=&55
50290 E=127
50300 CURSOR X,0:GPRINT E;D;0;C;127
50310 CURSOR X,1:GPRINT E;D;0;C;127
50320 X=5+B*4:C=0:D=0:E=0:IF II(B)<0LET C=&55
50330 IF B>=N-1GOTO 50360 
50340 IF II(B+1)<0LET D=&55
50350 E=127
50360 CURSOR X,0:GPRINT 127;C;0;D;E
50370 CURSOR X,1:GPRINT 127;C;0;D;E
50380 A=ASC INKEY$ :IF A<>0THEN 50380 
50390 RETURN 
50400 "PNT1"CURSOR X,0:GPRINT PT$(0);:GPRINT PT$(2);:GPRINT PT$(0);
50410 CURSOR X,1:GPRINT PT$(3);:GPRINT PT$(5);:GPRINT PT$(3);:RETURN 
50420 "PNT2"CURSOR X,0:GPRINT PT$(1);:GPRINT PT$(0);:GPRINT PT$(0);
50430 CURSOR X,1:GPRINT PT$(3);:GPRINT PT$(3);:GPRINT PT$(4);:RETURN 
50440 "PNT3"CURSOR X,0:GPRINT PT$(1);:GPRINT PT$(2);:GPRINT PT$(0);
50450 CURSOR X,1:GPRINT PT$(3);:GPRINT PT$(5);:GPRINT PT$(4);:RETURN 
50460 "PNT4"CURSOR X,0:GPRINT PT$(1);:GPRINT PT$(0);:GPRINT PT$(1);
50470 CURSOR X,1:GPRINT PT$(4);:GPRINT PT$(3);:GPRINT PT$(4);:RETURN 
50480 "PNT5"CURSOR X,0:GPRINT PT$(1);:GPRINT PT$(2);:GPRINT PT$(1);
50490 CURSOR X,1:GPRINT PT$(4);:GPRINT PT$(5);:GPRINT PT$(4);:RETURN 
50500 "PNT6"CURSOR X,0:GPRINT PT$(1);:GPRINT PT$(1);:GPRINT PT$(1);
50510 CURSOR X,1:GPRINT PT$(4);:GPRINT PT$(4);:GPRINT PT$(4);:RETURN